Tutorialen visar hur man jämför textsträngar i Excel med avseende på skiftlägen och exakt matchning. Du kommer att lära dig ett antal formler för att jämföra två celler med hjälp av deras värden, stränglängd eller antalet förekomster av ett visst tecken, samt hur du jämför flera celler.
När du använder Excel för dataanalys är noggrannhet det viktigaste. Felaktig information leder till missade tidsfrister, felbedömda trender, felaktiga beslut och förlorade intäkter.
Men även om Excel-formlerna alltid är helt sanna kan deras resultat vara felaktiga på grund av att några felaktiga data trängt in i systemet. I det här fallet är den enda lösningen att kontrollera att uppgifterna är korrekta. Det är ingen stor sak att jämföra två celler manuellt, men det är näst intill omöjligt att upptäcka skillnaderna mellan hundratals och tusentals textsträngar.
Denna handledning kommer att lära dig hur du automatiserar den tråkiga och felbenägna uppgiften att jämföra celler och vilka formler som är bäst att använda i varje enskilt fall.
- Hur man jämför 2 celler i Excel
- Hur man jämför flera celler
- Hur man jämför ett antal celler med en provcell
- Hur man jämför celler efter strängens längd
- Hur man jämför. strängar efter förekomst av ett visst tecken
Hur man jämför två celler i Excel
Det finns två olika sätt att jämföra strängar i Excel, beroende på om du vill använda fall-känslig eller om du vill göra en jämförelse utan att ta hänsyn till storleken på storleken.
Formel för att jämföra två celler utan hänsyn till kasus
För att jämföra två celler i Excel utan hänsyn till kasus använder du en enkel formel som denna:
=A1=B1
Varvid A1 och B1 är de celler du jämför. Resultatet av formeln är de booleska värdena TRUE och FALSE.
Om du vill skriva ut egna texter för överensstämmelser och skillnader bäddar du in ovanstående uttalande i det logiska testet i IF-funktionen. Till exempel:
=IF(A1=B1, "Equal", "Not equal")
Som du ser i skärmdumpen nedan jämför båda formlerna textsträngar, datum och siffror lika bra:
Formel som tar hänsyn till kasus för att jämföra strängar i Excel
I vissa situationer kan det vara viktigt att inte bara jämföra text i två celler, utan också att jämföra teckenkasus. En textjämförelse som tar hänsyn till storleken kan göras med Excel-funktionen EXACT:
Varvid text1 och text2 är de två celler som du jämför.
Antagen att dina strängar finns i cellerna A2 och B2, så ser formeln ut på följande sätt:
=EXACT(A2, B2)
Som resultat får du TRUE för textsträngar som matchar exakt, inklusive kasus för varje tecken, och FALSE i annat fall.
Om du vill att EXACT-funktionen ska ge några andra resultat bäddar du in den i en IF-formel och skriver din egen text för argumenten value_if_true och value_if_false:
=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")
Följande skärmdump visar resultatet av jämförelsen av strängar med hänsyn till stor- och småbokstäver i Excel:
Hur man jämför flera celler i Excel
Om du vill jämföra fler än två celler i en rad använder du formlerna som diskuteras i exemplen ovan i kombination med AND-operatorn. De fullständiga detaljerna följer nedan.
Formel för att jämföra fler än 2 celler
Avhängigt av hur du vill visa resultaten använder du en av följande formler:
=AND(A2=B2, A2=C2)
eller
=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")
Formeln AND returnerar TRUE (sant) om alla cellerna innehåller samma värde, FALSE (falskt) om något värde är annorlunda. Formeln IF ger ut de etiketter som du skriver i den, ”Lika” och ”Inte lika” i det här exemplet.
Som visas i skärmdumpen nedan fungerar formeln perfekt med alla datatyper – text, datum och numeriska värden:
Formel som tar hänsyn till storleken för att jämföra text i flera celler
För att jämföra flera strängar med varandra för att se om de stämmer exakt överens, använd följande formler:
=AND(EXACT(A2,B2), EXACT(A2, C2))
Och
=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")
Som i det föregående exemplet ger den första formeln värden som är riktiga och falska, medan den andra formeln visar dina egna texter för att se om de stämmer överens eller inte:
Genom att jämföra ett intervall av celler med en provcell
De följande exemplen visar hur du kan kontrollera att alla celler i ett visst intervall innehåller samma text som i en provcell.
Formel som inte tar hänsyn till kasus för att jämföra celler med en provtext
Om teckenkasus egentligen inte spelar någon roll kan du använda följande formel för att jämföra celler med ett prov:
I det logiska testet av IF-funktionen jämför du två tal:
- Det totala antalet celler i ett angivet intervall (antalet rader multiplicerat med antalet kolumner) och
- Antalet celler som innehåller samma värde som i provcellen (som returneras av funktionen COUNTIF).
Antagen att provtexten finns i C2 och att de strängar som ska jämföras finns i intervallet A2:B6, så ser formeln ut på följande sätt:
=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)
För att göra resultaten mer användarvänliga, dvs. att ge ut något som ”Alla matchar” och ”Inte alla matchar” i stället för TRUE och FALSE, använd IF-funktionen som vi gjorde i de tidigare exemplen:
=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")
Som framgår av ovanstående skärmdump klarar formeln perfekt ett intervall med textsträngar, men den kan också användas för att jämföra siffror och datum.
Formel som tar hänsyn till kasus för att jämföra strängar med en exempeltext
Om teckenkaskan gör skillnad kan du jämföra strängar med exempeltexten med hjälp av följande arrayformler.
Med källområdet i A2:B6 och exempeltexten i C2 får formeln följande form:
=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")
Under skillnad från vanliga Excel-formler kompletteras arrayformler genom att trycka på Ctrl + Shift + Enter. Om den skrivs in korrekt omsluter Excel matrisformeln med {kragar}, vilket visas i skärmdumpen:
Hur man jämför två celler efter strängens längd
Ibland vill du kanske kontrollera om textsträngarna i varje rad innehåller lika många tecken. Formeln för den här uppgiften är mycket enkel. Först tar du fram stränglängden för två celler med hjälp av funktionen LEN och jämför sedan siffrorna.
Antagen att de strängar som ska jämföras finns i cellerna A2 och B2, använd någon av följande formler:
=LEN(A2)=LEN(B2)
Och
=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")
Som du redan vet returnerar den första formeln de booleska värdena TRUE (sant) eller FALSE (falskt), medan den andra formeln matar ut dina egna resultat:
Som framgår av skärmdumpen ovan fungerar formlerna för textsträngar såväl som för siffror.
Genomföra två celler efter förekomst av ett visst tecken
Det här är det sista exemplet i vår handledning Excel Jämför strängar och visar en lösning för en ganska specifik uppgift. Antag att du har två kolumner med textsträngar som innehåller ett tecken som är viktigt för dig. Ditt mål är att kontrollera om två celler i varje rad innehåller samma antal förekomster av ett visst tecken.
För att göra saker och ting tydligare kan du tänka på följande exempel. Låt oss säga att du har två listor över beställningar som skickats (kolumn B) och mottagits (kolumn C). Varje rad innehåller beställningar för en specifik artikel, vars unika identifierare ingår i alla order-ID:n och som listas i samma rad i kolumn A (se skärmbilden nedan). Du vill försäkra dig om att varje rad innehåller lika många skickade och mottagna artiklar med det specifika ID:t.
För att lösa det här problemet skriver du en formel med följande logik:
- Först ersätter du den unika identifieraren med ingenting med hjälp av SUBSTITUTE-funktionen:
SUBSTITUTE(A1, character_to_count,"") - Därefter beräknar du hur många gånger den unika identifieraren förekommer i varje cell. För detta tar du fram strängens längd utan den unika identifieraren och subtraherar den från strängens totala längd. Denna del ska skrivas för cell 1 och cell 2 var för sig, till exempel:
LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))
ochLEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, "")) - Sist jämför du dessa 2 tal genom att placera likhetstecknet (=) mellan ovanstående delar.
LEN(cell 2) – LEN(SUBSTITUTE(cell 2, character_to_count, ””))
I vårt exempel står den unika identiteten i A2 och de strängar som ska jämföras står i cellerna B2 och C2. Så den fullständiga formeln är följande:
=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))
Formeln returnerar TRUE om cellerna B2 och C2 innehåller lika många förekomster av tecknet i A2, FALSE annars. För att göra resultaten mer meningsfulla för användarna kan du bädda in formeln i IF-funktionen:
=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")
Som du kan se i skärmdumpen ovan fungerar formeln perfekt, trots ett par ytterligare komplikationer:
- Tecknet som ska räknas (unik identifierare) kan förekomma var som helst i en textsträng.
- Strängarna innehåller ett varierande antal tecken och olika separatorer som semikolon, kommatecken eller mellanslag.
Så här jämför du strängar i Excel. Om du vill titta närmare på de formler som diskuteras i den här handledningen är du välkommen att ladda ner Excel-arbetsbladet Jämför strängar. Jag tackar dig för att du läste och hoppas att vi ses på vår blogg nästa vecka.
Du kanske också är intresserad av
- Genom att jämföra två kolumner i Excel för att se om de stämmer överens och skiljer sig åt
- Sättet att jämföra två Excel-arbetsblad för att se om de skiljer sig åt
- Hur man använder en logisk operatör för att jämföra tal
- 4 sätt att göra en skiftlägeskänslig vlookup i Excel
.