De zelfstudie laat zien hoe u tekstreeksen in Excel kunt vergelijken voor hoofdletterongevoelige en exacte overeenkomst. U leert een aantal formules om twee cellen te vergelijken op basis van hun waarden, tekenreekslengte of het aantal keren dat een specifiek teken voorkomt, evenals hoe u meerdere cellen kunt vergelijken.
Wanneer u Excel gebruikt voor gegevensanalyse, is nauwkeurigheid de meest essentiële zorg. Onjuiste informatie leidt tot gemiste deadlines, verkeerd ingeschatte trends, verkeerde beslissingen en gederfde inkomsten.
Hoewel Excel-formules altijd perfect waar zijn, kunnen hun resultaten verkeerd zijn omdat sommige gebrekkige gegevens in het systeem zijn doorgedrongen. In dit geval is de enige remedie het controleren van gegevens op nauwkeurigheid. Het is niet erg om twee cellen handmatig te vergelijken, maar het is bijna onmogelijk om de verschillen tussen honderden en duizenden tekststrings te spotten.
Deze tutorial leert u hoe u de vervelende en foutgevoelige taak van celvergelijking kunt automatiseren en welke formules in elk specifiek geval het beste kunnen worden gebruikt.
- Hoe 2 cellen te vergelijken in Excel
- Hoe meerdere cellen te vergelijken
- Vergelijk een bereik van cellen met een voorbeeld cel
- Cellen vergelijken op tekenreekslengte
- Vergelijk tekenreeksen op voorkomen van specifiek teken
Hoe vergelijkt u twee cellen in Excel
Er zijn twee verschillende manieren om tekenreeksen in Excel te vergelijken, afhankelijk van of u een hoofdlettergevoeligegevoelig of hoofdletterongevoelig wilt vergelijken.
Case-ongevoelige formule om 2 cellen te vergelijken
Om twee cellen in Excel te vergelijken zonder rekening te houden met hoofdletters, gebruikt u een eenvoudige formule als deze:
=A1=B1
Waar A1 en B1 de cellen zijn die u vergelijkt. Het resultaat van de formule zijn de Booleaanse waarden WAAR en ONWAAR.
Als u uw eigen teksten voor overeenkomsten en verschillen wilt uitvoeren, sluit u de bovenstaande verklaring in de logische test van de IF-functie in. Bijvoorbeeld:
=IF(A1=B1, "Equal", "Not equal")
Zoals u in de onderstaande schermafbeelding ziet, vergelijken beide formules tekstreeksen, datums en getallen even goed:
Hoofdlettergevoelige formule om tekenreeksen in Excel te vergelijken
In sommige situaties kan het belangrijk zijn om niet alleen tekst in twee cellen te vergelijken, maar ook de hoofdletters te vergelijken. Hoofdlettergevoelige tekstvergelijking kan worden uitgevoerd met de EXACT-functie van Excel:
Waarbij text1 en text2 de twee cellen zijn die u vergelijkt.
Aannemende dat uw tekenreeksen zich in de cellen A2 en B2 bevinden, gaat de formule als volgt:
=EXACT(A2, B2)
Als resultaat krijgt u WAAR voor tekenreeksen die precies overeenkomen, inclusief de hoofdletter van elk teken, en ONWAAR anders.
Als u wilt dat de EXACT-functie andere resultaten oplevert, sluit u deze in een IF-formule in en typt u uw eigen tekst voor de argumenten value_if_true en value_if_false:
=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")
De volgende schermafbeelding toont de resultaten van de hoofdlettergevoelige tekenreeksvergelijking in Excel:
Hoe meerdere cellen te vergelijken in Excel
Om meer dan 2 cellen in een rij te vergelijken, gebruikt u de formules die in de bovenstaande voorbeelden zijn besproken in combinatie met de operator AND. De volledige details volgen hieronder.
Hoofdletterongevoelige formule om meer dan 2 cellen te vergelijken
Afhankelijk van hoe u de resultaten wilt weergeven, gebruikt u een van de volgende formules:
=AND(A2=B2, A2=C2)
of
=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")
De AND-formule geeft WAAR als alle cellen dezelfde waarde bevatten, en ONWAAR als een waarde verschilt. De IF-formule voert de labels uit die u erin typt, “Gelijk” en “Niet gelijk” in dit voorbeeld.
Zoals in de onderstaande schermafbeelding wordt gedemonstreerd, werkt de formule perfect met alle gegevenstypen – tekst, datums en numerieke waarden:
Hoofdlettergevoelige formule om tekst in meerdere cellen te vergelijken
Om meerdere tekenreeksen met elkaar te vergelijken om te zien of ze exact overeenkomen, gebruikt u de volgende formules:
=AND(EXACT(A2,B2), EXACT(A2, C2))
Of
=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")
Zoals in het vorige voorbeeld levert de eerste formule WAAR en ONWAAR waarden op, terwijl de tweede uw eigen teksten weergeeft voor overeenkomsten en verschillen:
Vergelijk een cellenbereik met een voorbeeldcel
De volgende voorbeelden laten zien hoe u kunt controleren of alle cellen in een bepaald bereik dezelfde tekst bevatten als in een voorbeeldcel.
Hoofdletterongevoelige formule om cellen te vergelijken met een voorbeeldtekst
Als het hoofdlettergebruik er niet echt toe doet, kunt u de volgende formule gebruiken om cellen te vergelijken met een voorbeeld:
In de logische test van de IF-functie vergelijkt u twee getallen:
- Het totale aantal cellen in een gespecificeerd bereik (het aantal rijen vermenigvuldigd met het aantal kolommen), en
- Het aantal cellen dat dezelfde waarde bevat als in de monstercel (geretourneerd door de COUNTIF-functie).
Aannemende dat de voorbeeldtekst in C2 staat en dat de te vergelijken tekenreeksen in het bereik A2:B6 staan, gaat de formule als volgt:
=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)
Om de resultaten gebruikersvriendelijker te maken, d.w.z. iets te laten zien als “Alle komen overeen” en “Niet alle komen overeen” in plaats van WAAR en ONWAAR, gebruikt u de IF-functie zoals we in de vorige voorbeelden hebben gedaan:
=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")
Zoals de bovenstaande schermafbeelding laat zien, kan de formule perfect overweg met een reeks tekstreeksen, maar kan deze ook worden gebruikt om getallen en datums te vergelijken.
Hoofdlettergevoelige formule om tekenreeksen te vergelijken met een voorbeeldtekst
Als de hoofdletter een verschil maakt, kunt u tekenreeksen vergelijken met de voorbeeldtekst met behulp van de volgende matrixformules.
Met het bronbereik dat zich in A2:B6 en de voorbeeldtekst in C2, neemt de formule de volgende vorm aan:
=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")
In tegenstelling tot gewone Excel-formules worden matrixformules voltooid door op Ctrl + Shift + Enter te drukken. Als de formule correct is ingevoerd, omsluit Excel de matrixformule met {krullende accolades}, zoals wordt weergegeven in de schermafbeelding:
Hoe vergelijkt u twee cellen op tekenreekslengte
Soms wilt u misschien controleren of de tekenreeksen in elke rij een gelijk aantal tekens bevatten. De formule voor deze taak is heel eenvoudig. Eerst verkrijgt u de tekenreekslengte van twee cellen met behulp van de functie LEN, en vervolgens vergelijkt u de getallen.
In de veronderstelling dat de te vergelijken tekenreeksen zich in de cellen A2 en B2 bevinden, gebruikt u een van de volgende formules:
=LEN(A2)=LEN(B2)
Of
=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")
Zoals u al weet, geeft de eerste formule de Booleaanse waarden WAAR of ONWAAR terug, terwijl de tweede formule uw eigen resultaten weergeeft:
Zoals in de bovenstaande schermafbeelding wordt aangetoond, werken de formules zowel voor tekstreeksen als voor getallen.
Vergelijk twee cellen door het voorkomen van een specifiek teken
Dit is het laatste voorbeeld in onze Excel Vergelijk Strings tutorial, en het toont een oplossing voor een nogal specifieke taak. Stel, u heeft 2 kolommen met tekst strings die een karakter bevatten dat voor u belangrijk is. Uw doel is om te controleren of twee cellen in elke rij hetzelfde aantal occurrences van een bepaald karakter bevatten.
Om dingen duidelijker te maken, overweeg het volgende voorbeeld. Stel, u hebt twee lijsten met verzonden (kolom B) en ontvangen (kolom C) orders. Elke rij bevat orders voor een specifiek artikel, waarvan de unieke identificatie is opgenomen in alle order ID’s en is opgenomen in dezelfde rij in kolom A (zie de schermafbeelding hieronder). U wilt ervoor zorgen dat elke rij een gelijk aantal verzonden en ontvangen items met die specifieke ID bevat.
Om dit probleem op te lossen, schrijft u een formule met de volgende logica.
- Vervang eerst de unieke identifier door niets met behulp van de SUBSTITUTE functie:
SUBSTITUTE(A1, character_to_count,"") - Bereken vervolgens hoe vaak de unieke identifier in elke cel voorkomt. Bereken de lengte van de string zonder de unieke identificatiecode en trek deze af van de totale lengte van de string. Dit deel moet voor cel 1 en cel 2 afzonderlijk worden geschreven, bijvoorbeeld:
LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))
enLEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, "")) - Tot slot vergelijkt u deze 2 getallen door het gelijkheidsteken (=) tussen de bovenstaande delen te plaatsen.
LEN(cel 2) – LEN(SUBSTITUTE(cel 2, teken_tot_telling, “”))
In ons voorbeeld staat de unieke identificatiecode in A2, en de te vergelijken tekenreeksen staan in de cellen B2 en C2. De volledige formule is dus als volgt:
=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))
De formule geeft WAAR als cellen B2 en C2 een gelijk aantal occurrences bevatten van het teken in A2, en ONWAAR anders. Om de resultaten zinvoller te maken voor uw gebruikers, kunt u de formule inbedden in de IF-functie:
=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")
Zoals u in de bovenstaande schermafbeelding kunt zien, werkt de formule perfect, ondanks een paar extra complicaties:
- Het te tellen teken (unieke identificatie) kan overal in een tekststring voorkomen.
- De tekenreeksen bevatten een variabel aantal tekens en verschillende scheidingstekens zoals puntkomma, komma of spatie.
Dit is hoe u tekenreeksen vergelijkt in Excel. Om de formules die in deze handleiding worden besproken van dichterbij te bekijken, kunt u Excel Vergelijk strings werkblad downloaden. Ik dank u voor het lezen en hoop u volgende week op onze blog te zien.
U bent misschien ook geïnteresseerd in
- Vergelijk twee kolommen in Excel voor overeenkomsten en verschillen
- Hoe twee Excel-werkbladen te vergelijken voor verschillen
- Hoe logische operator te gebruiken om getallen te vergelijken
- 4 manieren om een hoofdlettergevoelige vlookup in Excel uit te voeren